source: sans/Analysis/branches/ajj_23APR07/IGOR_Package_Files/Put in User Procedures/SANS_Models_v3.00/Models_2D/Cylinder_2D.ipf @ 185

#pragma rtGlobals=1             // Use modern global access method.
#pragma IgorVersion=6.0

// "simple" version of 2D function
//
// The plotting macro sets up TWO dependencies
// - one for the triplet calculation
// - one for a matrix to display, a copy of the triplet
//
// For display, there are two copies of the matrix. One matrix is linear, and is a copy of the 
// triplet (which is ALWAYS linear). The other matrix is toggled log/lin for display
// in the same way the 2D SANS data matrix is handled.
//
// Nothing is threaded at this point, although I think it needs to be since upon
// reading of the WM documentation, it looks like only "basic" fit functions (meaning
// NOT AAO or Struct functions) are automatically threaded during curve fitting.
//
//

//Cylinder_2D_Dist()

// this is what Cylinder_2D_Dist() from our XOP is expecting
//double dist_cylinder_2D(double pars[], double q, double phi) {
//      SmearCylinderParameters danse_pars;
//      danse_pars.scale        = pars[0];
//      danse_pars.radius       = pars[1];
//      danse_pars.length       = pars[2];
//      danse_pars.contrast     = pars[3];
//      danse_pars.background   = pars[4];
//      danse_pars.cyl_theta    = pars[5];
//      danse_pars.cyl_phi      = pars[6];
//      danse_pars.sigma_theta  = pars[7];
//      danse_pars.sigma_phi    = pars[8];
//      danse_pars.sigma_radius = pars[9];
//
//      return smeared_cylinder_analytical_2D(&danse_pars, q, phi);     
//      
//};

//
// the calculation is done as for the QxQy data set:
// three waves XYZ, then converted to a matrix
//
Proc PlotCylinder2D(str)                                                
        String str
        Prompt str,"Pick the data folder containing the 2D data",popup,getAList(4)
        
        // if any of the resolution waves are missing => abort
//      if(ResolutionWavesMissingDF(str))               //updated to NOT use global strings (in GaussUtils)
//              Abort
//      endif
        
        SetDataFolder $("root:"+str)
        
        // Setup parameter table for model function
        make/O/T/N=10 parameters_Cyl2D
        Make/O/D/N=10 coef_Cyl2D
        coef_Cyl2D[0] = 1.0
        coef_Cyl2D[1] = 20.0
        coef_Cyl2D[2] = 60.0
        coef_Cyl2D[3] = 6.0e-6
        coef_Cyl2D[4] = 0.0
        coef_Cyl2D[5] = 1.57
        coef_Cyl2D[6] = 0.0
        coef_Cyl2D[7] = 0.0
        coef_Cyl2D[8] = 0.0
        coef_Cyl2D[9] = 0.0
        //NOT THE SAME ORDER AS MATHIEU'S CODE
        parameters_Cyl2D[0] = "Scale"
        parameters_Cyl2D[1] = "Radius"
        parameters_Cyl2D[2] = "Length"
        parameters_Cyl2D[3] = "Contrast"
        parameters_Cyl2D[4] = "Background"
        parameters_Cyl2D[5] = "Axis Theta"
        parameters_Cyl2D[6] = "Axis Phi"
        parameters_Cyl2D[7] = "Sigma of polydisp in Theta [rad]"
        parameters_Cyl2D[8] = "Sigma of polydisp in Phi [rad]"
        parameters_Cyl2D[9] = "Sigma of polydisp in Radius [A]"

        Edit parameters_Cyl2D,coef_Cyl2D                                        
        
        // generate the triplet representation
        Duplicate/O $(str+"_qx") xwave_Cyl2D
        Duplicate/O $(str+"_qy") ywave_Cyl2D,zwave_Cyl2D                        
                
        Variable/G gs_Cyl2D=0
        gs_Cyl2D := Cylinder2D(coef_Cyl2D,zwave_Cyl2D,ywave_Cyl2D,xwave_Cyl2D)  //AAO 2D calculation
        
        Display ywave_Cyl2D vs xwave_Cyl2D
        modifygraph log=0
        ModifyGraph mode=3,marker=16,zColor(ywave_Cyl2D)={zwave_Cyl2D,*,*,YellowHot,0}
        ModifyGraph standoff=0
        ModifyGraph width={Aspect,1}
        ModifyGraph lowTrip=0.001
        Label bottom "q (\\S-1\\M)"
        Label left "q (\\S-1\\M)"
        AutoPositionWindow/M=1/R=$(WinName(0,1)) $WinName(0,2)
        
        // generate the matrix representation
        ConvertQxQy2Mat(xwave_Cyl2D,ywave_Cyl2D,zwave_Cyl2D,"Cyl2D_mat")
        Duplicate/O $"Cyl2D_mat",$"Cyl2D_lin"           //keep a linear-scaled version of the data
        // _mat is for display, _lin is the real calculation

        Variable/G gs_Cyl2Dmat=0
        gs_Cyl2Dmat := UpdateQxQy2Mat(xwave_Cyl2D,ywave_Cyl2D,zwave_Cyl2D,Cyl2D_lin,Cyl2D_mat)
        
        
        SetDataFolder root:
        AddModelToStrings("Cylinder2D","coef_Cyl2D","Cyl2D")
End


//AAO version, uses XOP if available
// simply calls the original single point calculation with
// a wave assignment (this will behave nicely if given point ranges)
//
// NON-THREADED IMPLEMENTATION
//
//Function Cylinder2D(cw,zw,yw,xw) : FitFunc
//      Wave cw,zw,yw,xw
//      
//#if exists("Cylinder_2D_Dist")
//      zw = Cylinder_2D_Dist(cw,yw,xw)
//#else
//      Abort "You do not have the SANS Analysis XOP installed"
//#endif
//      return(0)
//End
//

//threaded version of the function
ThreadSafe Function Cylinder2D_T(cw,zw,yw,xw,p1,p2)
        WAVE cw,zw,yw,xw
        Variable p1,p2
        
        zw[p1,p2]= Cylinder_2D_Dist(cw,yw,xw)

//      return stopMSTimer(-2)          // time when we finished
        return 0
End

//function that is actually a wrapper to dispatch the calculation to N threads
//
Function Cylinder2D(cw,zw,yw,xw) : FitFunc
        Wave cw,zw,yw,xw
        
        Variable npt=numpnts(yw)
        Variable i,nthreads= ThreadProcessorCount
        variable mt= ThreadGroupCreate(nthreads)

        for(i=0;i<nthreads;i+=1)
//              Print (i*npt/nthreads),((i+1)*npt/nthreads-1)
                ThreadStart mt,i,Cylinder2D_T(cw,zw,yw,xw,(i*npt/nthreads),((i+1)*npt/nthreads-1))
        endfor

        do
                variable tgs= ThreadGroupWait(mt,100)
        while( tgs != 0 )

        variable dummy= ThreadGroupRelease(mt)
        
        return(0)
End