Changeset 224

Timestamp:

Dec 5, 2007 4:42:16 PM (15 years ago)

Author:

srkline

Message:

Updated files for an "improved" way of assigning transmission files. works with a shift-click on the transmission file and a table hook to do the search. User gets to say y/n to the match. no cutting or pasting needed.

Location:

sans/SANSReduction/trunk/Put in User Procedures/SANS_Reduction_v5.00

Files:

• Includes_v500.ipf (modified) (1 diff)
• MainPanel.ipf (modified) (2 diffs)
• NSORT.ipf (modified) (1 diff)
• SANS_Utilities.ipf (modified) (1 diff)
• Transmission.ipf (modified) (3 diffs)

sans/SANSReduction/trunk/Put in User Procedures/SANS_Reduction_v5.00/Includes_v500.ipf

@@ -65 +65 @@
 Menu "SANSBeta"
         "FillEMPUsingSelection"
-        "GuessEveryTransFiles"
+        "GuessEveryTransFile"
         "GuessSelectedTransFiles"
         "ClearSelectedTransAssignments"

sans/SANSReduction/trunk/Put in User Procedures/SANS_Reduction_v5.00/MainPanel.ipf

@@ -237 +237 @@
         Button MainButtonC,pos={250,8},size={50,20},proc=HelpMainButtonProc,title="Help"
         Button MainButtonC,help={"Display the help file"}
+        Button MainButtonD,pos={320,8},size={80,20},proc=SR_OpenTracTicketPage,title="Feedback"
+        Button MainButtonD,help={"Submit bug reports or feature requests"}
         
         TabControl MainTab,pos={7,49},size={410,202},tabLabel(0)="Raw Data",proc=MainTabProc
@@ -360 +362 @@
 End
 
+//
+Function SR_OpenTracTicketPage(ctrlName)
+        String ctrlName
+        DoAlert 1,"Your web broser will open to a page where you can submit your bug report or feature request. OK?"
+        if(V_flag==1)
+                BrowseURL "http://danse.chem.utk.edu/trac/newticket"
+        endif
+End
 
 //********************************

sans/SANSReduction/trunk/Put in User Procedures/SANS_Reduction_v5.00/NSORT.ipf

@@ -1719 +1719 @@
                                                 //Print "combine the files"
                                                 SendSelectionToTable()
-                                                break;
+                                                break
         //                              case "no":
-        //                                      break;
+        //                                      break
         //                              case "maybe":
         //                                      // do something because "maybe" was chosen
-        //                                      break;
+        //                                      break
                                 endswitch               //on selection
                         endif

sans/SANSReduction/trunk/Put in User Procedures/SANS_Reduction_v5.00/SANS_Utilities.ipf

@@ -235 +235 @@
 End
 
-Proc GuessEveryTransFiles(num)
+Proc GuessEveryTransFile(num)
         Variable num=6
         GuessAllTransFiles(num)

sans/SANSReduction/trunk/Put in User Procedures/SANS_Reduction_v5.00/Transmission.ipf

@@ -158 +158 @@
         
         Edit/K=1/W=(30,30,500,250) T_EMP_Filenames, T_Filenames, T_Labels, T_SDD, T_Lambda, T_Transmission, T_Whole as "TransmissionFiles"
+        
+        SetWindow kwTopWin hook=GuessFromTableHook, hookevents=1        // mouse down events
+        
         String name="TransFileTable"
         DoWindow/C $name
@@ -1554 +1557 @@
 End
 
-//given a selection of the sample files, try to find the corresponding transmission file
+//given a selection of the SAMPLE files, try to find the corresponding transmission file
 //
 Function GuessTransFile(charsToUse,row)
@@ -1605 +1608 @@
 End
 
+//given a single transmission file, try to find the corresponding scattering file(s)
+//
+// apply TWO criteria
+// (1) the label must match "well enough"
+// (2) the wavelength must be the same
+//
+// passes the matching rows in the sample table back
+//
+Function GuessTransToScattFiles(charsToUse,row,matchRows)
+        Variable charsToUse,row                 //number of characers to use from the beginning of the label, and the row of the transmission file
+        Wave matchRows          //rows where (potential) matches found. initially zero points
+        
+        Wave/T sw = root:myGlobals:TransHeaderInfo:S_Labels             //Sample file labels
+        Wave/T tw = root:myGlobals:TransHeaderInfo:T_Labels             //trans file labels
+        Wave/T tnam = root:myGlobals:TransHeaderInfo:T_FileNames        //trans file names
+        Wave/T snam = root:myGlobals:TransHeaderInfo:S_TRANS_FileNames  //Scattering - trans correspondence
+        Wave sLam = root:myGlobals:TransHeaderInfo:S_Lambda             //Scattering file wavelength
+        Wave tLam = root:myGlobals:TransHeaderInfo:T_Lambda             //Transmission file wavelength
+        
+        Variable num,ii,found
+        String transStr = "",testStr=""
+        
+        transStr = (tw[row])[0,charsToUse-1]            //string to try and match
+        transStr += "*"
+        
+        //loop over ALL sample files
+        num=numpnts(sw)
+        ii=0
+        do
+                testStr=sw[ii]
+                found = stringmatch(testStr, transStr )
+                if( (found == 1) && (sLam[ii] == tLam[row]) )           // both must match
+                        Print "Match Found at:  ",transStr,snam[ii],sw[ii]
+                        InsertPoints numpnts(matchRows), 1, matchRows
+                        matchRows[numpnts(matchRows)-1] = ii
+                endif
+                ii+=1
+        while(ii<num)
+        
+        //method 2 *UNTESTED*
+//      transStr = (tw[row])[0,charsToUse-1]            //string to try and match
+//      num=numpnts(sw)
+//      ii=0
+//      do
+//              testStr=sw[ii]
+//              found = strsearch(testStr,transStr,0,2)         //start from zero, ignore case
+//              if(found != -1)
+//                      Print "Match Found at:  ",transStr,snam[ii],sw[ii]
+//                      InsertPoints numpnts(matchRows), 1, matchRows
+//                      matchRows[numpnts(matchRows)-1] = ii
+////                    snam[ii] = tnam[row]                    //write the file name into the table
+//              endif
+//              ii+=1
+//      while(ii<num)
+        
+//      Print "No Match found"
+        return(0)
+End
+
+//get a single selection from the Trans table
+// find all of the matching scattering files (rows)
+// ask the user if the selections are OK
+// if NOT OK, do nothing
+// if OK: make the assignments, and immediately calculate the transmission
+//
+Function fGuessTransToScattFiles(numChars)
+        Variable numChars
+        
+        Variable ii,row
+        Variable transTableExists
+        Make/O/D/N=0 root:myGlobals:TransHeaderInfo:matchRows
+        Wave matchRows=root:myGlobals:TransHeaderInfo:matchRows
+        
+        transTableExists = WinType("TransFileTable")
+        if (transTableExists != 0)
+                GetSelection table,transFileTable,1     
+                row = V_startRow
+                GuessTransToScattFiles(numChars,row,matchRows)
+        else
+                Print "Transmission->Scattering File table is not open"
+                return (1)
+        endif
+        
+        Wave/T sw = root:myGlobals:TransHeaderInfo:S_Labels             //Sample file labels
+        Wave/T tw = root:myGlobals:TransHeaderInfo:T_Labels             //trans file labels
+        Wave/T tnam = root:myGlobals:TransHeaderInfo:T_FileNames        //trans file names
+        Wave/T snam = root:myGlobals:TransHeaderInfo:S_TRANS_FileNames  //Scattering - trans correspondence
+        
+        Variable num=numpnts(matchRows)
+        String result="",tmpStr
+        for(ii=0;ii<num;ii+=1)
+                sprintf tmpStr,"%s* Matches file: %s %s\r",(tw[row])[0,numChars-1],snam[matchRows[ii]],sw[matchRows[ii]]
+                result += tmpStr
+        endfor
+        
+        if(cmpstr(result,"")==0)
+                result = "No match found for "+ (tw[row])[0,numChars-1]
+        endif
+        
+        Print result
+        Print "*******"
+        
+        String/G root:myGlobals:TransHeaderInfo:gResultStr = result
+        DoWindow/F ConfirmGuess         //it really shouldn't exist...
+        if(V_flag==1)
+                TitleBox title0,pos={9,5},variable=root:myGlobals:TransHeaderInfo:gResultStr
+        else
+                NewPanel /W=(763,44,1284,181) as "Confirm Guess"
+                DoWindow/C ConfirmGuess
+                TitleBox title0,pos={9,5},size={501,32}
+                TitleBox title0,variable= root:myGlobals:TransHeaderInfo:gResultStr
+                Button button0,pos={9,107},size={190,20},proc=DoAssignTransButtonProc,title="Assign Transmission Files"
+                Button button2,pos={341,108},size={90,20},proc=DoTryAgainButtonProc,title="Try Again"
+                ToolsGrid snap=1,visible=1
+        endif
+        
+        PauseForUser ConfirmGuess
+// figure out from the return code what the user did...
+// 1 = OK, accept guess (assign, and calculate immediately)
+// 2 = try again
+// 0 = cancel, don't do anything (not used, simply try again)
+        NVAR guessOK = root:myGlobals:TransHeaderInfo:GuessOK
+        
+        // switch here...
+        switch(guessOK) // numeric switch
+                case 1:         
+                        // accept guess (assign, and calculate immediately)
+                        for(ii=0;ii<num;ii+=1)
+                                snam[matchRows[ii]] = tnam[row]
+                                AssignSelTransFilesToData(matchRows[ii],matchRows[ii])
+                                CalcSelTransFromHeader(matchRows[ii],matchRows[ii])             //does only that sample file
+                        endfor                  
+                        break                                           
+                case 2: //try again (with more / fewer characters?)     
+                        //              does nothing right now
+                        break
+                case 0:
+                        // do nothing
+                        break
+                default:                                                        
+                        //      do nothing                                      
+        endswitch
+        
+        return(0)
+End
+
+// a hook attached to the Transmission Files Table
+// given a single selected Trans File, popup gives choices
+// to guess using "n" characters, then dispatch accordingly
+Function GuessFromTableHook(infoStr)
+        String infoStr
+        String event= StringByKey("EVENT",infoStr)
+//      Print "EVENT= ",event
+
+        String menuStr=""
+        menuStr += "Guess using 3 characters;"
+        menuStr += "Guess using 6 characters;"
+        menuStr += "Guess using 9 characters;"
+        menuStr += "Guess using 12 characters;"
+        menuStr += "Guess using 15 characters;"
+        menuStr += "Guess using 18 characters;"
+        
+        strswitch(event)
+                case "mousedown":
+                        Variable xpix= NumberByKey("MOUSEX",infoStr)
+                        Variable ypix= NumberByKey("MOUSEY",infoStr)
+                        Variable modif= NumberByKey("MODIFIERS",infoStr)
+                        //print modif
+                        if(modif & 2^1)         //bit 1 set, shift key is down
+                                PopupContextualMenu/C=(xpix, ypix) menuStr
+                                strswitch(S_selection)
+                                        case "Guess using 3 characters":
+                                                fGuessTransToScattFiles(3)
+                                                break
+                                        case "Guess using 6 characters":
+                                                fGuessTransToScattFiles(6)
+                                                break
+                                        case "Guess using 9 characters":
+                                                fGuessTransToScattFiles(9)
+                                                break
+                                        case "Guess using 12 characters":
+                                                fGuessTransToScattFiles(12)
+                                                break
+                                        case "Guess using 15 characters":
+                                                fGuessTransToScattFiles(15)
+                                                break
+                                        case "Guess using 18 characters":
+                                                fGuessTransToScattFiles(18)
+                                                break
+                                endswitch               //on selection
+                        endif
+        endswitch       // on event
+        
+        return 0
+End
+
+// sets a flag if the user thinks that the guess was correct, and wants to use the
+// identified files for the transmission
+Function DoAssignTransButtonProc(ba) : ButtonControl
+        STRUCT WMButtonAction &ba
+
+        switch( ba.eventCode )
+                case 2: // mouse up
+                        // click code here
+                        //Print "Assigned stuff, and left."
+                        Variable/G root:myGlobals:TransHeaderInfo:GuessOK= 1
+                        DoWindow/K ConfirmGuess
+                        break
+        endswitch
+
+
+        return 0
+End
+
+// files are wrong, let the user try it again
+// sets a flag, nothing else
+Function DoTryAgainButtonProc(ba) : ButtonControl
+        STRUCT WMButtonAction &ba
+
+        switch( ba.eventCode )
+                case 2: // mouse up
+                        // click code here
+                        Variable/G root:myGlobals:TransHeaderInfo:GuessOK= 2
+                        DoWindow/K ConfirmGuess
+                        //Print "Try Again"
+                        break
+        endswitch
+        
+        return 0
+End
+
+// not used
+Function DoCancelGuessButtonProc(ba) : ButtonControl
+        STRUCT WMButtonAction &ba
+
+        switch( ba.eventCode )
+                case 2: // mouse up
+                        // click code here
+                        //just kill the panel, don't do anything
+                        Variable/G root:myGlobals:TransHeaderInfo:GuessOK= 0
+                        DoWindow/K ConfirmGuess
+                        break
+        endswitch
+        
+        return 0
+End
+
 Function GuessAllTransFiles(numChars)
         Variable numChars